2019年6月21日 星期五

[Arduino] 實做一個文字跑馬燈(二) -- 使用手機發送訊息給 8*32 點陣 LED

在上一個實驗 (https://pizgchen.blogspot.com/2019/06/arduino-led-max7219-832-led.html)
當中文內有提到,可以用 Serial Monitor 視窗輸入文字改變顯示訊息,由此可知應該也可以手機透過藍牙傳送資料來改變顯示的訊息,這樣的話能讓使用者更加方便切換訊息,另一方面也能有更多的應用。本實驗就是修改上一個實驗,讓我們可以用手機來改變顯示的訊息。



在硬體方面,您需要一支智慧型手機、一片藍牙模組和杜邦線4P。HC-05 是具有主從模式的模組,此處我們採用 BT06 藍牙模組,它相容於 HC-06 ,只有"從"模式。有兩點理由讓我們採用 BT06 藍牙模組,一是這個實驗在 Arduino 點陣 LED 這端不需要主動連線手機,因此只需要"從"模式就可以;二是它價錢比 HC-05 便宜。




接線

接續上個實驗,現在把4P杜邦線再接上 BT06 藍牙模組,另一頭如下接法:

Arduino      BT06
Vcc             Vcc
Gnd            Gnd
D8              TXD
D9              RXD

藍牙模組的 STATE 和 EN 針脚可以省略不用。

原始 Software Serial 函式庫裡的範例是接 D10 & D11,這裡之所以改接 D8 & D9 是因為 D10、D11、D13 已被點陣 LED 佔用。

另外,這片藍牙模組的預設參數如下所示:

NAME = BT04-A
BAUD RATE = 9600
PASSWORD = 1234

瞭解這些參數有利於您在手機端的藍牙設定,還有 Arduino 端的程式設定。


Arduino 程式

我們參考了 Software Serial 函式庫裡的範例,把下列幾行程式碼加入上個實驗的程式內:

#include <SoftwareSerial.h>
SoftwareSerial mySerial(8, 9); // RX, TX
mySerial.begin(9600);

並修改函示 readSerial() 部份內容,完整 Arduino 程式碼如下:

#include <SoftwareSerial.h>
#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>

// set to 1 if we are implementing the user interface pot, switch, etc
#define USE_UI_CONTROL 0

#if USE_UI_CONTROL
#include <MD_UISwitch.h>
#endif

// Turn on debug statements to the serial output
#define DEBUG 0

#if DEBUG
#define PRINT(s, x) { Serial.print(F(s)); Serial.print(x); }
#define PRINTS(x) Serial.print(F(x))
#define PRINTX(x) Serial.println(x, HEX)
#else
#define PRINT(s, x)
#define PRINTS(x)
#define PRINTX(x)
#endif

// Define the number of devices we have in the chain and the hardware interface
// NOTE: These pin numbers will probably not work with your hardware and may
// need to be adapted
#define HARDWARE_TYPE MD_MAX72XX::PAROLA_HW
#define MAX_DEVICES 4
#define CLK_PIN   13
#define DATA_PIN  11
#define CS_PIN    10

SoftwareSerial mySerial(8, 9); // RX, TX

// HARDWARE SPI
MD_Parola P = MD_Parola(HARDWARE_TYPE, CS_PIN, MAX_DEVICES);
// SOFTWARE SPI
//MD_Parola P = MD_Parola(HARDWARE_TYPE, DATA_PIN, CLK_PIN, CS_PIN, MAX_DEVICES);

// Scrolling parameters
#if USE_UI_CONTROL
const uint8_t SPEED_IN = A5;
const uint8_t DIRECTION_SET = 8;  // change the effect
const uint8_t INVERT_SET = 9;     // change the invert

const uint8_t SPEED_DEADBAND = 5;
#endif // USE_UI_CONTROL

uint8_t scrollSpeed = 25;    // default frame delay value
textEffect_t scrollEffect = PA_SCROLL_LEFT;
textPosition_t scrollAlign = PA_LEFT;
uint16_t scrollPause = 2000; // in milliseconds

// Global message buffers shared by Serial and Scrolling functions
#define BUF_SIZE 75
char curMessage[BUF_SIZE] = { "" };
char newMessage[BUF_SIZE] = { "Robot Wolf Group" };
bool newMessageAvailable = true;

#if USE_UI_CONTROL

MD_UISwitch_Digital uiDirection(DIRECTION_SET);
MD_UISwitch_Digital uiInvert(INVERT_SET);

void doUI(void)
{
  // set the speed if it has changed
  {
    int16_t speed = map(analogRead(SPEED_IN), 0, 1023, 10, 150);

    if ((speed >= ((int16_t)P.getSpeed() + SPEED_DEADBAND)) ||
      (speed <= ((int16_t)P.getSpeed() - SPEED_DEADBAND)))
    {
      P.setSpeed(speed);
      scrollSpeed = speed;
      PRINT("\nChanged speed to ", P.getSpeed());
    }
  }

  if (uiDirection.read() == MD_UISwitch::KEY_PRESS) // SCROLL DIRECTION
  {
    PRINTS("\nChanging scroll direction");
    scrollEffect = (scrollEffect == PA_SCROLL_LEFT ? PA_SCROLL_RIGHT : PA_SCROLL_LEFT);
    P.setTextEffect(scrollEffect, scrollEffect);
    P.displayClear();
    P.displayReset();
  }

  if (uiInvert.read() == MD_UISwitch::KEY_PRESS)  // INVERT MODE
  {
    PRINTS("\nChanging invert mode");
    P.setInvert(!P.getInvert());
  }
}
#endif // USE_UI_CONTROL

void readSerial(void)
{
  static char *cp = newMessage;

  while (mySerial.available())
  {
    *cp = (char)mySerial.read();
    if ((*cp == '\n') || (cp - newMessage >= BUF_SIZE-2)) // end of message character or full buffer
    {
      *cp = '\0'; // end the string
      // restart the index for next filling spree and flag we have a message waiting
      cp = newMessage;
      newMessageAvailable = true;
    }
    else  // move char pointer to next position
      cp++;
  }
}

void setup()
{
  Serial.begin(57600);
  Serial.print("\n[Parola Scrolling Display]\nType a message for the scrolling display\nEnd message line with a newline");

  mySerial.begin(9600);
  mySerial.println("Robot Wolf Group -- LED Matrix");
  
#if USE_UI_CONTROL
  uiDirection.begin();
  uiInvert.begin();
  pinMode(SPEED_IN, INPUT);

  doUI();
#endif // USE_UI_CONTROL

  P.begin();
  P.displayText(curMessage, scrollAlign, scrollSpeed, scrollPause, scrollEffect, scrollEffect);
}

void loop()
{
#if USE_UI_CONTROL
  doUI();
#endif // USE_UI_CONTROL

  if (P.displayAnimate())
  {
    if (newMessageAvailable)
    {
      strcpy(curMessage, newMessage);
      newMessageAvailable = false;
    }
    P.displayReset();
  }
  
  readSerial(); 
  
}


手機 APP

下載並安裝手機 APP (Android) 

https://www.dropbox.com/s/fe3vuxl7d1w0bk8/LED_Matrix.apk?dl=0

開啟 APP 後會先出現要求您啟用藍牙設備的訊息,您同意後再選擇要連線的藍牙裝置,然後會出現下列畫面:


點按 [Connect] 鈕連線藍牙,連線後在 Display 文字欄內輸入文字,按下 [Send] 鈕就可以改變點陣 LED 上的訊息。

在 [Send] 鈕下方有三個按鈕,按下後會直接把預設好的訊息傳出,
[<<<] 鈕會傳出 "<<<",這可以代表自行車的左轉燈;
[>>>] 鈕會傳出 ">>>",這可以代表自行車的右轉燈;
[STOP] 鈕會傳出 "STOP",這可以代表自行車的煞車燈。



結論

由於點陣 LED 目前的動態顯示方式是由右而左捲動文字,在操作過程當中可以感覺到左右轉燈和煞車燈顯示的方式並非是我們所想要的。其實,原始程式預留多種動態顯示方式,這部份我們留待下回再來做個探討。


延伸資料

Arduino bluetooth controled 8*32 LED Matrix https://electronoobs.com/eng_arduino_tut14.php


採購資訊












沒有留言:

張貼留言